Anemometr TX23 a Wi-Fi ESP8266

#include <ESP8266WiFi.h>
#include <ESP8266WiFi.h>
#include <ESP8266HTTPClient.h>

// nastaveni wifi
const char* ssid = "mojewifi";
const char* password = "supertajneheslo";
int failedWiFi = 0;


// struktura na data z TX23 a globani promenna vitr
typedef struct {
  unsigned char  smer;          // smer vetru 0-16
  unsigned int   rychlost;      // rychlost vetru v 0.1m/s, 0-512
  unsigned char  crc;           // kontrolni soucet
  unsigned char  smerInv;       // bitove invertovany smer
  unsigned int   rychlostInv;   // bitove invertovana rychlost
} TX23;
TX23 vitr;


// pin pripojeny na sbernici cidla TX23
// pres pullup rezistor 4k7 k 3V3
#define DATAPIN D2


// http client
HTTPClient http;
uint16_t httpFails = 0;

// casovac
uint32_t prevTime = 0;


// ------------------------------------------------------------------------------------------------
// SETUP
// ------------------------------------------------------------------------------------------------
void setup() {

  // -- disable SW wdt --
  ESP.wdtDisable();

  // -- seriovy port jako info konzole --
  Serial.begin(115200);

  // -- vychozi IO stav pinu pripojeneho na sbernici s TX23 --
  pinMode(DATAPIN, INPUT);

  // -- pripojeni do wifi --
  int maxRetries = 20;
  Serial.print("[WiFi] connecting...");
  WiFi.persistent(false); // neukladame nic do Flash - setrime ji
  WiFi.mode(WIFI_STA);
  WiFi.disconnect();
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(1000);
    Serial.print('.');
    ESP.wdtFeed();
    if (!maxRetries--) while (1);
  }
  Serial.println(WiFi.localIP());

}
// ------------------------------------------------------------------------------------------------




// ------------------------------------------------------------------------------------------------
// LOOP
// ------------------------------------------------------------------------------------------------
void loop() {

  unsigned char i, err;


  if ((millis() - prevTime) >= 5000) {
    prevTime = millis();
    i = 3;
    while (i--) {
      err = readData(&vitr);
      Serial.println();
      Serial.print("Smer:     "); Serial.println(vitr.smer);
      Serial.print("Rychlost: "); Serial.println(vitr.rychlost);
      Serial.print("ErrCode:  "); Serial.println(err);
      if (err == 0) break;
    }
    sendviahttp(&vitr, err);

  }

  // -- smazani psa --
  ESP.wdtFeed();
}
// ------------------------------------------------------------------------------------------------





// ------------------------------------------------------------------------------------------------
// Funkce na precteni dat z anemometeru Lacrosse TX23U
// Vstup:    v - ukazatel pro promennou struktury TX23
// Vystup:   0 = vse je OK
//           1 = selhalo cekani na vzestupnou hranu prvniho bitu hlavicky
//           2 = selhalo cekani na sestupnou hrannu druheho bitu hlavicky
//           3 = hodnota zmerenoho bitrate je mimo meze
//           4 = chyba pri kontrole hodnoty smeru vetru
//           5 = chyba pri kontrole hodnoty rychlosti vetru
//           5 = chyba kontrolniho souctu
//           7 = cidlo nereaguje na start signal
// ------------------------------------------------------------------------------------------------
unsigned char readData(TX23 *v) {

  uint32_t bitrate, timeoutCnt;
  unsigned char k = 0, i = 0, b, crc;

  // -- smazani starych hodnot --
  v->smer = 0;
  v->rychlost = 0;
  v->crc = 0;
  v->smerInv = 0;
  v->rychlostInv = 0;

  // -- start signal, na 500ms stahneme sbernici na low --
  digitalWrite(DATAPIN, 0);
  pinMode(DATAPIN, OUTPUT);
  delay(500);
  pinMode(DATAPIN, INPUT);

  // -- po 1.2ms musi cidlo sbernici stahnout do low, pockame 5ms a zkontrolujeme --
  delay(5);
  if (digitalRead(DATAPIN) != 0) return (7);

  // -- nyni pockame na vzestupnou hranu prvniho bitu hlavicky a poznamename si cas --
  timeoutCnt = 2000000;
  while (digitalRead(DATAPIN) == 0) if (!timeoutCnt--) return (1);
  bitrate = micros();
  // -- nyni pockame na sestupnou hranu druheho bitu hlavicky a vypocitame bitrate --
  while (digitalRead(DATAPIN) == 1) if (!timeoutCnt--) return (2);
  bitrate = (micros() - bitrate) >> 1;
  // -- zkontrolujeme meze bitrate, standarte by melo byt 1200, lita to ale od 1217 do 1222 --
  if ( (bitrate < 1000) || (bitrate > 1400) ) return (3);

  // -- pockame 3.5 nasobek bitrate, dostaneme se tak na prostredek prvniho bitu po hlavicce --
  delayMicroseconds((uint16_t) 3 * bitrate + (bitrate >> 1) );

  // -- provedeme 36 cteni urovne sbernice s krokem bitrate --
  // -- dle poradi bitu zarazujeme do jednotlivych polozek struktury TX23
  // -- pri zapisu se otaci poradi bitu dle MSB->LSB, cidlo posila LSB jako prvni --
  while (i++ < 36) {
    b = digitalRead(DATAPIN);
    //Serial.print(b);
    if (i == 1) k = 0;
    if (i >= 1 && i <= 4) v->smer |= b << k++;
    if (i == 5) k = 0;
    if (i >= 5 && i <= 16) v->rychlost |= b << k++;
    if (i == 17) k = 0;
    if (i >= 17 && i <= 20) v->crc |= b << k++;
    if (i == 21) k = 0;
    if (i >= 21 && i <= 24) v->smerInv |= b << k++;
    if (i == 25) k = 0;
    if (i >= 25 && i <= 36) v->rychlostInv |= b << k++;
    delayMicroseconds((uint16_t) bitrate);
  }

  // -- kontrola, zda-li hodnota smeru odpovida invertovane hodnote --
  if (v->smer != ((~v->smerInv) & 0x0F)) return (4);

  // -- kontrola, zda-li hodnota rychlosti odpovida invertovane hodnote --
  if (v->rychlost != ((~v->rychlostInv) & 0x0FFF)) return (5);

  // -- vypocet CRC a porovnani s tim, co poslalo cidlo --
  crc = v->smer;
  crc += v->rychlost & 0x0F;
  crc += (v->rychlost >> 4) & 0x0F;
  crc += (v->rychlost >> 8) & 0x0F;
  crc = crc & 0x0F;
  if (v->crc != crc) return (6);

  // -- pokud vse dopadne dobre --
  return (0);

}
// ------------------------------------------------------------------------------------------------



// ------------------------------------------------------------------------------------------------
// Odeslani dat o vetru pres http get (verze funkcni 16.7.2021 s aktualnimi knihovnami)
// Vstup:    v - ukazatel pro promennou struktury TX23
//           errcode - navratova hodnota mereni cidla vetru
// ------------------------------------------------------------------------------------------------
void sendviahttp(TX23 *v, uint8_t errcode) {
  if ((WiFi.status() == WL_CONNECTED)) {
    WiFiClient client;
    HTTPClient http;
    char sendBuffer[500];
    sprintf(sendBuffer, "http://www.example.com/obsluhacidla.php?smer=%d&rychlost=%d&errcode=%d", v->smer, v->rychlost, errcode);
    if (http.begin(client, sendBuffer)) {
      int httpCode = http.GET();
      Serial.printf("http get return code: %d\n", httpCode);
      if (httpCode > 0) {
        if (httpCode == HTTP_CODE_OK || httpCode == HTTP_CODE_MOVED_PERMANENTLY) {
          Serial.print("http get response: ");
          String payload = http.getString();
          Serial.println(payload);
          httpFails = 0;
        }
      } else {
        Serial.printf("http get failed, error: %s\n", http.errorToString(httpCode).c_str());
        httpFails++;
      }
      http.end();
    } else {
      Serial.println("http get failed, unable to connect");
      httpFails++;
    }
  }
  if (httpFails > 180) while (1);
}
// ----------------------------------------------------------------------------------------------
  
  
  

<?php
  foreach ($_GET as $val) if(!is_numeric($val)) die('int error');
  file_put_contents("data.dat", json_encode($_GET));
?>

<html>
<head>
  <meta http-equiv="Content-Type" content="text/html; charset=windows-1250" />
  <META HTTP-EQUIV="Cache-Control" CONTENT="no-cache" />
  <META HTTP-EQUIV="pragma" CONTENT="no-cache" />
  <META HTTP-EQUIV="Expires" CONTENT="0" />
  <meta http-equiv="refresh" content="5">
</head>
<body>
<h1>Vitr</h1>
<pre>
<?php
$pole = json_decode(file_get_contents("data.dat"));
echo "Modtime = " . date ("d.m.Y H:i:s", filemtime("data.dat")) . "<br>";
echo "Rychlost: ".$pole->speed*0.32." km/h<br>";
$smer = array(
  0=>'sever (0°)',
  1=>'severo-severovýchod (22.5°)',
  2=>'severovýchod (45°)',
  3=>'východo-severovýchod (67.5°)',
  4=>'východ (90°)',
  5=>'východo-jihovýchod (112.5°)',
  6=>'jihovýchod (135°)',
  7=>'jiho-jihovýchod (157.5°)',
  8=>'jih (180°)',
  9=>'jiho-jihozápad (202.5°)',
  10=>'jihozápad (225°)',
  11=>'západo-jihozápad (247.5°)',
  12=>'západ (270°)',
  13=>'západo-severozápad (292.5°)',
  14=>'severozápad (315°)',
  15=>'severo-severozápad (337.5°)'  
);
echo "Smer: ".$smer[$pole->direction]."<br>";
?>
</pre>
</body>

$x=0;
$y=0;
foreach ($smer as $poleSmeru) {
  $x += sin( $smer * (pi()/8) );
  $y += cos( $smer * (pi()/8) );	 
}
$uhel = rad2deg(atan2($x, $y));
if($uhel<0) $uhel = 360 + $uhel;

$smerPrumer = $uhel / (360/16);